批处理文件操作杂记

由于某些原因,一些文件夹出现了前缀..和后缀.hider.hider,而且文件加里包含文件夹和文件,应该是肯定在1000的工作量的,尝试用纯的批处理写出来,不过一直到最后都还是没有弄明白用什么办法可以刚刚把匹配后的字符串取出来,应该用正则可以办到,但是没有找到系统介绍批处理中正则的资料,故想写一个c++程序来处理。无奈,不调用复杂的系统API似乎还是很难做到(我还没系统研究io.h和direct.h里面到底包含哪些函数),而WinAPI似乎总是希望传达你一个宏大的思想,需要注意的细节太多。

最总写成了如下版本的两个文件,先是批处理

@echo off&setlocal enabledelayedexpansion

PATH I:\tmp\Orginal\
a.exe
for /r %%a in (dir /ad) do (

     cd %%~pa
     a.exe
)
#include   <stdio.h> 
#include   <io.h> 
#include   <direct.h> 
#include <cstring>
#include <iostream>


using namespace std;


typedef   struct   _finddata_t   file_block; 

int main() 
{ 
    file_block   f_block; 
    long   handle,retcode; 
    int flag;
    handle=_findfirst("*",&f_block); 
    do{
        printf( "%-12s\n ",f_block.name);
        char tmp[1505],fn[1257];
        strcpy(fn,f_block.name);
        flag=1;
        while(fn[0]=='.')
        {
            int l=strlen(fn);
            for(int i=1;i<=l;i++)
              fn[i-1]=fn[i];
            flag=0;
        }
        {
            int len=strlen(fn);
            for(int i=0;i<len-1;i++)
              if(fn[i]=='.' && fn[i+1]=='h' && fn[i+2]=='i' && fn[i+3]=='d'
                 && fn[i+4]=='e' && fn[i+5]=='r')
                 fn[i]='\0',flag=0;
        }
        /*
        if(flag)
        {
            cout<<fn<<endl;
            continue;
        }
        */
        strcpy(tmp,"ren \"");
        strcat(tmp,f_block.name);
        strcat(tmp,"\" \"");
        strcat(tmp,fn);
        strcat(tmp,"\"");
        cout<<"$"<<tmp<<endl;
        system(tmp);
        retcode=_findnext(handle,&f_block); 
    }while(retcode==0); 
    printf( "\n   end   of   diretory\n "); 
    //system("pause");
    return 0;
}

 

另外附一份批处理的资料

批处理文件小结因为很多游戏资源的处理都是通过DOS批处理文件来进行的,所以必须要了解批处理文件的语法。下面把比较重要的内容一一列举出来。
注意command.com和cmd.exe是不同的东西。command.com是MS-DOS的命令解释器(shell),没有它,大部分的Windows系统都是无法引导的,从MS-DOS到WinXP都需要它。cmd.exe是更高级的shell,它提供了许多环境变量,支持的平台是WinNT、Win2K、WinXP、Vista和Win7。而且二者的命令行参数也是不一样的。
下面所说的都是基于cmd.exe的。

>>> @
描述:从 DOS 3.3 开始,可以用它来隐藏DOS命令的显示。注意,只是隐藏命令,并不会隐藏命令的输出。
语法:放在任何DOS命令前面;也可以放在批处理文件名的前面。
示例:
@echo OFF 将隐藏这七个后续字母的显示

>>> %0 - %9
描述:用于引用命令行上的参数。
语法:%0是命令行的批处理命令。%1 - %9是后面的九个参数。
示例:
E:\MYBATCH DOC A: 命令行
COPY *.%1 %2      MYBATCH.BAT文件内容:只有一行。复制所有的DOC文件到软驱。

>>> %variable%
描述:引用变量。比较简单,直接示例。
示例:
echo The current search path is: %PATH%
set USER=John
if %USER%==John goto LABEL

当Command Extensions启用时,有下面几个系统变量:
echo %cd%             显示当前目录。如果当前目录是各个驱动器的根目录,则后面有反斜杠\;反之则没有。
echo %date%
echo %time%
echo %random%         0到32767之间的随机数
echo %errorlevel%     见下文
echo %cmdextversion%  见下文
echo %cmdcmdline%     命令行

变量值替换:
@echo OFF
set USER_PROMPT=Please input a string:
echo %USER_PROMPT:~7,5%       变量值的临时替换。offset=7,length=5。也就是input这五个字母。
echo %USER_PROMPT:~7%         不指定length,则默认是后面全部。也就是 input a string: 这一大串。
echo %USER_PROMPT:~-7%        offset为负值,则从后往前数。length还是往后全部。也就是string:这七个字母。
echo %USER_PROMPT:~-7,6%      length为6,则为string这六个字母。
echo %USER_PROMPT%            原来的变量值不变。
pause

延迟变量展开:
@echo off
set VAR=before
if "%VAR%" == "before" (
set VAR=after
echo %VAR%                    会输出什么?很大可能是before,而不是after。因为默认情况下,“延迟变量展开”(delayed environment variable expansion)是禁用的。
)
一般来说,这可不是我们想要的。因为默认情况下,cmd.exe在读入批处理文件之后,立刻把变量VAR全部展开成before了,然后才开始执行脚本。
cmd.exe的/v开关可以打开,以支持“延迟变量展开”,使得变量可以在执行阶段变化。然后变量的使用也要变化:
@echo off
set VAR=before
if "%VAR%" == "before" (
set VAR=after
echo !VAR!                  此时会输出after。
echo %VAR%                  还是输出before。
)

同样,下面的程序:
set FILE_LIST=
for %i in (*) do set FILE_LIST=!FILE_LIST! %i
echo !FILE_LIST!              输出当前目录的所有文件
echo %FILE_LIST%              也输出当前目录的所有文件,为什么?

可以用setlocal enabledelayedexpansion在批处理文件中打开该选项。

>>> echo
描述:控制DOS命令与注释的显示与否。
语法:echo [ON|OFF|message|.]
示例:
echo  显示当前echo状态是开是关
echo ON | OFF 不言自明
echo Processing... 在屏幕上显示 Processing... 这条消息
echo %USER%  在屏幕上显示 USER 变量的值
echo.  显示一个空行
echo Y|Del *.*  删除所有文件,在问:Are you sure 的时候,用Y来响应。

>>> call
描述:调用别的批处理文件。
语法:
从 DOS 3.3 开始:call [drive:][path]filename [batch-parameters]
DOS 3.3 以前的版本:command /c [drive:][path]filename [batch-parameters]

>>> for
描述:最重要的命令之一。很复杂。所以,下面的语法和示例要搀在一起来讲,就叫“用法”吧。
用法:它可以直接应用于命令行,当然也可以用于批处理文件内部。但是二者的使用是有差别的。
命令行的语法格式:FOR %variable IN (set) DO command [command-parameters]
1> 注意,其参数格式是%variable,如果用于批处理文件,则为%%variable。
2> variable是从a到z的字母,大小写敏感。
3> set是一个或多个文件。互相之间用空格或逗号隔开。支持通佩符。
例:
for %%i in (A,C,D) do dir %%i *.* 显示这几个驱动器的所有文件
for %%i in (*.*) do @echo %%i 显示当前目录的所有文件

当cmd.exe的 command extensions 开关打开时(默认就是打开),for命令还支持 /D /R /L /F 四个选项(大小写不敏感)。

/D
描述:目录操作
语法:FOR /D %variable IN (set) DO command [command-parameters]
示例:
for /d %%i in (*) do @echo %%i 显示当前目录的所有子目录
for /d %%i in ("%cd%\*") do @echo %%i 显示这些子目录的完整路径,加上双引号是为了表示带空格的目录,如果%cd%带空格的话。
for /d %%i in (c:\*) do @echo %%i 显示c盘下所有子目录
for /d %%i in (???) do @echo %%i 显示只有1-3个字母的目录

/R
描述:大概是recursive的意思。会递归遍历文件夹。
语法:FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
示例:
for /r e:\tmp %%i in (*.txt) do @echo %%i 显示该目录内的所有的txt文件。
for /r e:\tmp %%i in (boot.ini) do @if exist %%i echo %%i 如果该目录内有boot.ini文件,打印其完整路径。

/L
描述:数字循环。
语法:FOR /L %variable IN (start,step,end) DO command [command-parameters]
示例:
for /l %%i in (1,1,5) do @echo %%i 打印出1 2 3 4 5
for /l %%i in (1,1,5) do start cmd 打开5个cmd窗口

/F
描述:解析文件。读出文件集中的每个文件。按行处理。把每一行按delims指定的分隔符分成若干份。每一份都用变量去引用。处理完一个文件,继续处理下一个。
语法:
FOR /F ["options"] %variable IN (file-set) DO command [command-parameters]
FOR /F ["options"] %variable IN ("string") DO command [command-parameters]
FOR /F ["options"] %variable IN ('command') DO command [command-parameters]

如果文件名有空格,则需要在options中指定usebackq选项,那么命令格式变为:
FOR /F ["options"] %variable IN (file-set) DO command [command-parameters] file-set用双引号括起来
FOR /F ["options"] %variable IN ('string') DO command [command-parameters]
FOR /F ["options"] %variable IN (`command`) DO command [command-parameters]

options里的选项有:
eol=c  end-of-line字符。行结束符。遇到它认为该行结束,转而处理下一行。
skip=n 可以忽略文件开头的n行。默认情况下,每一行前面的空白也会被忽略。空行也会被忽略。
delims=xxx 指定分隔符可以用哪些字符。默认的分隔符是space和tab。
tokens=x,y,m-n 使用该行里的哪一部分。x和y是第几部分;m-n是从哪里到哪里。可以使用*号,代表该行后面所有的内容。
usebackq 表示要在后面的set里使用back quoted string来代表命令。没有该选项时,命令是用单引号(single quoted mark)来括起来的。

示例:
for /f "eol=; tokens=2,3* delims=, " %%i in (myfile.txt) do @echo %%i %%j %%k
1> myfile.txt 这个文件名没有带空格,所以不必使用usebackq选项。
2> eol=; 表示以分号开头的每一行都被忽略。
3> tokens=2,3* 表示要使用其第二块、第三块,第三块后面的所有东西作为第四块。分别用%%i、%%j和%%k来引用它们。
4> delims=, 表示分隔符是space和comma。

for /f "tokens=1,3 delims=;" %i in ("A red fox;is jumping;over a lazy dog") do @echo %i %j
将显示 A red fox over a lazy dog

for /f "usebackq delims==" %i IN (`set`) DO @echo %i
会运行set命令,然后捕捉其输出作为一个文件。最后显示出所有的变量。

>>> if
描述:条件判断
语法:
1> if [not] errorlevel number command
2> if [not] string1==string2 command
3> if [not] exist file_name command

errorlevel是由外部命令返回给cmd.exe的,是cmd.exe的内部定义变量。很多DOS命令执行完毕都会返回一个errorlevel。正常返回一般是0。
可以用C/c++编个小程序,main函数的return就可以返回errorlevel给DOS。
如果想查询某个DOS命令的errorlevel,一是查询microsoft网站,二是直接在控制台用echo %errorlevel%命令来查询。
如果想在某个批处理中返回一个errorlevel给更上层的批处理,那么用 exit /b 2。/b表示退出批处理,而非cmd.exe,2是errorlevel。

4> else也可以使用。需要注意的是,最好用括号把前面后面的东西都包起来,以免DOS把else当成前面命令的参数。cmd.exe对格式要求很严,必须像下面那样才行:

@echo OFF
for /r %%i in (for.txt) do (  // <1> 这半个括号绝对不能放到下面
if exist %%i (    // <2> 这半个括号绝对不能放到下面
echo %%i
) else (            // <3> else绝对要和这两个括号紧挨着
echo error...
)
)

当cmd.exe的 command extensions 启用时,又支持下面的语法:
1> if [/I] string1 compare-op string2 command
2> if CMDEXTVERSION number command
3> if DEFINED variable command

/I 开关表示大小写不敏感
compare-op 是比较操作符号:
EQU - 相等
NEQ - 不等
LSS - 小于
LEQ - 小于等于
GTR - 大于
GEQ - 大于等于
==  - 相等

CMDEXTVERSION 是 Command Extensions 的内部版本号
DEFINED 就像exist一样,会返回真或假

下面是常用的几种if语句的写法:
if errorlevel 3 goto ERROR_3
if errorlevel 2 goto ERROR_2
if errorlevel 1 goto ERROR_1
if errorlevel 0 echo Success.
goto BATCH_END

注意,一般errorlevel是倒序着写的。因为如果errorlevel为2,那么 if errorlevel 0 到 if errorlevel 2 都为真!
或者用更为直白的方式:
if %errorlevel% equ 0 goto SUCCESS
if %errorlevel% equ 1 goto ERROR_1
if %errorlevel% equ 2 goto ERROR_2
if %errorlevel% equ 3 goto ERROR_3

还有一种常用的嵌套写法:
if errorlevel 1 if not errorlevel 2 goto ERROR_1 大于等于1小于2,其实就是等于1了

字符串比较,是区分大小写的,同时不能出现等号(=)、分号(;)、管道(|)、重定向(<和>):
if (%1)==(LTrs) cd c:\word   当%1为空时,即没有参数时,会引发系统出错。所以一般不这么写,下面有两个小技巧解决这个问题。

在等号两边都加上词尾X,即使参数为空,也不会引发系统出错了,这是一个小技巧。
if not %2X==X dir %2\*.*  当存在第二个参数时,显示所有文件。

还有一个小技巧:
if "%1"=="" goto ERROR_NULL_PARAM

>>> SET
描述:显示、设置、删除cmd.exe的环境变量。
语法:
SET [variable=[string]]
当Command Extensions启用时,多了三个功能:
1> SET P  会显示所有以P开头的变量。
2> SET /A expression  /A说明要进行数学表达式计算。
3> SET /P variable=[promptString]  /P说明要接收用户输入给变量赋值,promptString是给用户的提示,可为空。

下面是表达式符号,优先级下降:
()           - 分组
! ~ -        - 单目运算符号
* / %        - 乘除模
+ -          - 加减
<< >>        - 移位
&            - 位与
^            - 位异或
|            - 位或
= *= /= %= += -= &= ^= |= <<= >>=     - 赋值
,            - 逗号表达式
1> 支持变量定义,使用时不用加%了。如果未定义而直接使用,默认值为零。
2> 支持十六进制(前缀0x)和八进制(前缀0),所以不要写出08和09这样的非法数字。

示例:
set    显示所有环境变量
set USER= 删掉USER变量 | USER置空
set PATH=%PATH%;c:\my_work  不言自明

@echo OFF
set USER_PROMPT=Please input a string: 
set /p JXD=%USER_PROMPT%
echo You just input:
echo %JXD%
echo.
echo Begin to substitute a string...
echo %USER_PROMPT:input=type%
pause

>>> shift
描述:如果想用%1引用所有的参数,或者命令行参数多于九个,那么需要用shift来移动参数的位置。
直接看示例:
:LOOP
copy %1 A:\
shift
if not (%1)==() goto LOOP

>>> 输入输出重定向
描述:cmd.exe这个shell程序支持四个I/O流——标准输入、标准输出、错误输出、控制台输出
示例:
echo Hello world>NUL 隐藏标准输出

下面故意打错了echo命令:
ehco Hello world>nul          cmd.exe会报错。这说明我们隐藏了标准输出,却没有隐藏错误输出。
ehco Hello world>nul 2>nul    这样的话,没有错误信息了。
ehco Hello world>con          输出到控制台

或者:echo Hello world 2>nul    这样的话,只是隐藏出错信息,屏幕上还是会显示出正确结果。

test.bat > test.txt 2>&1      把标准输出和错误输出都定向到一个文件里。
test.bat 2> test.txt 1>&2     同上。

在批处理中,如果有内容一定要输出到屏幕,应该写:>con。这样,批处理文件在执行时,即使被重定向,控制台上还是会输出一些信息。

在 WinNT 4、早期的Win2K和OS/2里,下面的输入应该小心:
echo Hello world2>log.txt
在这些平台上,会把 Hello world 输出到屏幕,同时产生一个空文件。即,它们把和>相连的2作为特殊字符了。而在WinXP里,则把 Hello world2 输出到log.txt里。
为了避免这样的二义性问题,要写成下面这样:
1> echo Hello world2 >log.txt
2> (echo Hello world2)>log.txt

重定向到其它命令:
one_command 2>&1 | another_command

 

批处理(for)For
对一组文件中的每个文件运行指定的命令。

语法
for {%Variable | %%Variable} in (Set) do Command [CommandLineOptions]

参数
{%Variable | %%Variable}

必需。代表可替换的参数。使用 %Variable 通过命令提示符执行 for 命令。使用 %%Variable 在批处理文件中执行 for 命令。变量要区分大小写,并且必须用 Alpha 值表示,例如,%A、%B 或 %C。

(Set)

必需。指定要用指定命令处理的一个或多个文件、目录、数值范围以及文本字符串。需要括号。

Command

必需。指定要对包括在指定的 (Set) 中每个文件、目录、数值范围或文本字符串所执行的命令。

CommandLineOptions

指定要与所指定命令一起使用的任何命令行选项。

/?

在命令提示符下显示帮助。

注释 " 
使用 for

可以在批处理文件中或直接从命令提示符使用 for 命令。

" 
使用批处理参数

下列属性适用于 for 命令:

" 
for 命令用 Set 中指定的每个文本字符串替换 %Variable 或 %%Variable,直到 Command 处理完所有文件为止。

" 
For Variable 名是区分大小写、全局的,并且每次活动的总共不超过 52 个。

" 
要避免混淆批处理参数 %0 到 %9,可对 Variable 使用除数字 0 到 9 之外的任何字符。对于简单的批处理文件,单个字符即可生效,例如 %%f。

" 
在复杂的批处理文件中可以使用多个 Variable 值来区分不同的可替换变量。

" 
指定一组文件

Set 参数可以代表单个或多个文件组。可以使用通配符(即 * 和 ?)指定文件组。以下为有效文件组:

(*.doc)

(*.doc *.txt *.me)

(jan*.doc jan*.rpt feb*.doc feb*.rpt)

(ar??1991.* ap??1991.*)

在使用 for 命令时,Set 中的第一个值代替 %Variable 或 %%Variable,然后由指定的命令处理该值。这会持续到处理完与 Set 值相对应的所有文件(或文件组)为止。

" 
使用 in 和 do 关键字

In 和 do 不是参数,但必须将它们与 for 一起使用。如果省略其中任何一个关键字,就会出现错误消息。

" 
使用 for 的其他格式

如果启用命令扩展(这是默认设置),则支持 for 的下列其他格式:

" 
仅目录

如果 Set 包含通配符(* 和 ?),将对与 Set 相匹配的每个目录(而不是指定目录中的文件组)执行指定的 Command。语法是:

for /D {%% | %}Variable in (Set) do Command [CommandLineOptions]

" 
递归

进入根目录树 [Drive:]Path,在树的每个目录中执行 for 语句。如果在 /R 后没有指定目录,则认为是当前目录。如果 Set 只是一个句点 (.),则只枚举目录树。语法是:

for /R [[Drive:]Path] {%% | %}Variable in (Set) do Command [CommandLineOptions]

" 
迭代数值范围

使用迭代变量设置起始值 (Start#),然后逐步执行一组范围的值,直到该值超过所设置的终止值 (End#)。/L 将通过对 Start# 与 End# 进行比较来执行迭代变量。如果 Start# 小于 End#,就会执行该命令。如果迭代变量超过 End#,则命令解释程序退出此循环。还可以使用负的 Step# 以递减数值的方式逐步执行此范围内的值。例如,(1,1,5) 生成序列 1 2 3 4 5,而 (5,-1,1) 则生成序列 (5 4 3 2 1)。语法是:

for /L {%% | %}Variable in (Start#,Step#,End#) do Command [CommandLineOptions]

" 
迭代及文件解析

使用文件解析来处理命令输出、字符串及文件内容。使用迭代变量定义要检查的内容或字符串,并使用各种 ParsingKeywords 选项进一步修改解析方式。使用 ParsingKeywords 令牌选项指定哪些令牌应该作为迭代变量传递。请注意:在没有使用令牌选项时,/F 将只检查第一个令牌。

文件解析过程包括读取输出、字符串或文件内容,将其分成独立的文本行以及再将每行解析成零个或更多个令牌。然后通过设置为令牌的迭代变量值,调用 for 循环。默认情况下,/F 传递每个文件每一行的第一个空白分隔符号。跳过空行。语法的不同点为:

for /F ["ParsingKeywords"] {%% | %}Variabe lin (FileNameSet) do Command [CommandLineOptions]

for /F ["ParsingKeywords"] {%% | %}Variable in ("LiteralString") do Command [CommandLineOptions]

for /F ["ParsingKeywords"] {%% | %}Variable in ('Command') do Command [CommandLineOptions]

FileNameSet 参数指定一个或多个文件名称。每个文件都将被打开、读取和处理,然后再继续执行 FileNameSet 中的下一个文件。要覆盖默认解析行为,请指定 "ParsingKeywords"。这是一个引号括起来的字符串,它包含一个或多个关键字以指定不同的解析选项。

如果使用 usebackq 选项,请使用如下语法之一:

for /F ["usebackqParsingKeywords"] {%% | %}Variable in ("FileNameSet") do Command [CommandLineOptions]

for /F ["usebackqParsingKeywords"] {%% | %}Variable in ('LiteralString') do Command [CommandLineOptions]

for /F ["usebackqParsingKeywords"] {%% | %}Variable in ('Command') do Command [CommandLineOptions]

下面列出可以用于 ParsingKeywords 的解析关键字。

关键字 描述 
eol=c

指定行尾字符(仅一个字符)。

skip=N

指定在文件的开头跳过的行数。

delims=xxx

指定分隔符集合。这将替换空格和制表符这一默认分隔符集。

tokens=X,Y,M-N

指定将哪些令牌从每行传递到每个迭代的 for 正文。这样就分配了附加变量名称。M-N 格式是一个范围,指定从第 M 个到第 N 个令牌。如果 tokens= 字符串中最后一个字符是星号 (*),那么将分配另外的变量,并接收解析的最后一个令牌之后该行剩余的文本。

usebackq

指定可以使用引号引用 FileNameSet 中的文件名,将后面带有引号的字符串作为一个命令执行,而带有单引号的字符串是文字字符串命令。

" 
变量替换

已经增强了 for 变量引用的替换修饰符。下面列出可选语法(对于任意变量 I)。

带有修饰符的变量 描述 
%~I

展开 %I,删除任何前后引号 ("")。

%~fI

将 %I 展开为完全限定的路径名。

%~dI

只将 %I 展开到驱动器号。

%~pI

只将 %I 展开到路径。

%~nI

只将 %I 展开到文件名。

%~xI

只将 %I 展开到文件扩展名。

%~sI

展开路径只包含短名称。

%~aI

将 %I 展开到文件的文件属性。

%~tI

将 %I 展开到文件的日期和时间。

%~zI

将 %I 展开到文件的大小。

%~$PATH:I

搜索 PATH 环境变量所列出的目录,并将 %I 展开到第一个找到的完全限定的名称。如果没有定义环境变量名称,或通过搜索没有找到文件,则此修饰符将扩展成空字符串。

下面列出了可用来获得复合结果的修饰符组合。

使用组合修饰符的变量 描述 
%~dpI

只将 %I 展开到驱动器号和路径。

%~nxI

只将 %I 展开到文件名和扩展名。

%~fsI

将 %I 展开到只包含短名称的完整路径名。

%~dp$PATH:I

在 PATH 环境变量中所列出的目录中搜索 %I,并将其展开到第一个找到的驱动器号和路径。

%~ftzaI

将 %I 展开到输出行(如 dir 一样)。

在上述示例中,可以用其他有效值替换 %I 和 PATH。有效的 for 变量名终止 %~ 语法。

使用大写变量名(例如 %I),可以使代码更具可读性,并且避免与不区分大小写的修饰符混淆。

" 
解析字符串

通过将 FileNameSet 用单引号括起来,(即 'FileNameSet'),可以使用 for /F 对直接字符串进行逻辑解析。系统将 FileNameSet 视为从某个文件输入的单行,然后对其进行解析。

" 
解析输出

通过将圆括号内的 FileNameSet 变为后面带有引号的字符串,可以利用 for /F 命令解析命令输出。此命令被视为命令行传递给子命令 Cmd.exe,并将输出捕获到内存并进行解析,就象它是一个文件一样。


示例
要在批处理文件中使用 for,请使用以下语法:

for %%Variable in (Set) do Command [CommandLineOptions]

要通过使用可替换变量 %f 显示当前目录中扩展名为 .doc 或 .txt 的所有文件的内容,请键入:

for %f in (*.doc *.txt) do type %f

在前述示例中,当前目录中扩展名为 .doc 或 .txt 的每个文件都被替代为变量 %f,直到每个文件的内容都被显示出来为止。要在批处理文件中使用此命令,请使用 %%f 替换所有的 %f。否则,系统将忽略该变量并显示一条错误消息。

要解析文件,同时忽略注释行,请键入:

for /F "eol=; tokens=2,3* delims=," %i in (myfile.txt) do @echo %i %j %k

此命令将解析 myfile.txt 文件的每一行,忽略以分号开头的行,将第二和第三个令牌从各行传递到 FOR 正文中(令牌通过逗号或空格分隔)。FOR 语句的正文引用 %i 获得第二个令牌,引用 %j 获得第三个令牌,引用 %k 获得其余全部令牌。如果您提供的文件名包含空格,请使用引号将文本引起来(例如,"File Name")。要使用引号,则必须使用 usebackq。否则,引号将被解释为定义要解析的文字字符串。

在 FOR 语句中显式声明 %i。使用 tokens= 隐式声明 %j 和 %k。只要不会引起试图声明高于字母“z”或“Z”的某个变量,则使用 tokens= 可以指定最多 26 个令牌。

要通过将 FileNameSet 放在括号中间来解析命令输出,请键入:

for /F "usebackq delims==" %i IN ('set') DO @echo %i

这个示例枚举了当前环境中的环境变量名。

格式图例 格式 意义 
斜体

用户必须提供的信息

粗体

用户必须像显示的一样准确键入的元素

省略号 (...)

可在命令行中重复多次的参数

在括号 ([]) 之间

可选项目

在大括号 ({}) 之间;将选项用管线 (|) 隔开。例如:{even|odd}

用户必须从中只选择一个选项的选项组

Courier font

代码或程序输出

自动获取分区下的所有文件夹(包括子文件夹),如果有同名的exe文件就把那个文件夹的属性改回来并删除那个exe文件:

@echo off
for %%i in (c d e f g h i j k l m n o p q r s t u v w z y z) do call :DF %%i
goto :EOF

:DF
for /f "delims=" %%a in ('dir %1:\ /b /ad /s') do (
attrib "%%~dpna" -s -h
del "%%~dpna.exe" /f /q /a 1>nul 2>nul
)
goto :EOF

 

FOR这条命令基本上都被用来处理文本,但还有其他一些好用的功能! 

看看他的基本格式(这里我引用的是批处理中的格式,直接在命令行只需要一个%号) 
FOR 参数 %%变量名 IN (相关文件或命令) DO 执行的命令 

参数:FOR有4个参数 /d   /l   /r   /f   他们的作用我在下面用例子解释 
%%变量名 :这个变量名可以是小写a-z或者大写A-Z,他们区分大小写,FOR会把每个读取到的值给他; 
IN:命令的格式,照写就是了; 
(相关文件或命令) :FOR要把什么东西读取然后赋值给变量,看下面的例子 
do:命令的格式,照写就是了! 
执行的命令:对每个变量的值要执行什么操作就写在这. 

可以在CMD输入for /?看系统提供的帮助!对照一下 
FOR %%variable IN (set) DO command [command-parameters] 

%%variable 指定一个单一字母可替换的参数。 
(set)      指定一个或一组文件。可以使用通配符。 
command    指定对每个文件执行的命令。 
command-parameters 
为特定命令指定参数或命令行开关。 


现在开始讲每个参数的意思 

/d 
仅为目录 
如果 Set (也就是我上面写的 "相关文件或命令") 包含通配符(* 和 ?),将对与 Set 相匹配的每个目 

录(而不是指定目录中的文件组)执行指定的 Command。 

系统帮助的格式:FOR /D %%variable IN (set) DO command 
他主要用于目录搜索,不会搜索文件,看这样的例子 

@echo off 
for /d %%i in (*) do @echo %%i 
pause 

把他保存放在C盘根目录执行,就会把C盘目录下的全部目录名字打印出来,而文件名字一个也不显示! 
在来一个,比如我们要把当前路径下文件夹的名字只有1-3个字母的打出来 

@echo off 
for /d %%i in (???) do @echo %%i 
pause 

这样的话如果你当前目录下有目录名字只有1-3个字母的,就会显示出来,没有就不显示了 


思考题目: 

@echo off 
for /d %%i in (window?) do @echo %%i 
pause 

保存到C盘下执行,会显示什么呢?自己看吧! 
/D参数只能显示当前目录下的目录名字,这个大家要注意! 

/R 
递归 
进入根目录树 [Drive:]Path,在树的每个目录中执行 for 语句。如果在 /R 后没有指定目录,则认为是 

当前目录。如果 Set 只是一个句点 (.),则只枚举目录树。 
系统帮助的格式:FOR /R [[drive:]path] %%variable IN (set) DO command 

上面我们知道,/D只能显示当前路径下的目录名字,那么现在这个/R也是和目录有关,他能干嘛呢?放心他比 

/D强大多了! 
他可以把当前或者你指定路径下的文件名字全部读取,注意是文件名字,有什么用看例子! 

@echo off 
for /r c:\ %%i in (*.exe) do @echo %%i 
pause 

咋们把这个BAT保存到D盘随便哪里然后执行,我会就会看到,他把C盘根目录,和每个目录的子目录下面全部 

的EXE文件都列出来了,这里的c:\就是目录了。 

再来一个 
@echo off 
for /r %%i in (*.exe) do @echo %%i 
pause 

参数不一样了,这个命令前面没加那个C:\也就是搜索路径,这样他就会以当前目录为搜索路径,比如你这 

个BAT你把他防灾d:\test目录下执行,那么他就会把D:\test目录和他下面的子目录的全部EXE文件列出 

来!!! 


/L 
迭代数值范围 
使用迭代变量设置起始值 (Start#),然后逐步执行一组范围的值,直到该值超过所设置的终止值 (End#) 

。/L 将通过对 Start# 与 End# 进行比较来执行迭代变量。如果 Start# 小于 End#,就会执行该命令。 

如果迭代变量超过 End#,则命令解释程序退出此循环。还可以使用负的 Step# 以递减数值的方式逐步执 

行此范围内的值。例如,(1,1,5) 生成序列 1 2 3 4 5,而 (5,-1,1) 则生成序列 (5 4 3 2 1)。语法是: 

系统帮助的格式:for /L %% Variable in (Start#,Step#,End#) do Command 

例如: 

@echo off 
for /l %%i in (1,1,5) do @echo %%i 
pause 

保存执行看效果,他会打印从1 2 3 4 5 这样5个数字 
(1,1,5)这个参数也就是表示从1开始每次加1直到5终止! 

再看这个例子 
@echo off 
for /l %%i in (1,1,5) do start cmd 
pause 

执行后是不是吓了一跳,怎么多了5个CMD窗口,呵呵!如果把那个 (1,1,5)改成 (1,1,65535)会有什么结果, 

我先告诉大家,会打开65535个CMD窗口....这么多你不死机算你强! 

当然我们也可以把那个start cmd改成md %%i 这样就会建立指定个目录了!!!名字为1-65535 

看完这个被我赋予破坏性质的参数后,我们来看最后一个参数 

/f 

含有/F的for详细说明 

含有/F的for有很大的用处,在批处理中使用的最多,用法如下: 
格式: 
FOR /F ["options"] %%i IN (file) DO command 

FOR /F ["options"] %%i IN ("string") DO command 

FOR /F ["options"] %%i IN ('command') DO command 

这个可能是最常用的,也是最强的命令,主要用来处理文件和一些命令的输出结果。 

file代表一个或多个文件 

string 代表字符串 

command代表命令 

["options"] 可选 

对于FOR /F %%i IN (file) DO command 

file为文件名,按照官方的说法是,for会依次将file中的文件打开,并且在进行到下一个文件之前将每个文件读取到内存,按照每一行分成一个一个的元素,忽略空白的行,看个例子。 

假如文件a.txt中有如下内容: 

第1行第1列 第1行第2列 第1行第3列 
第2行第1列 第2行第2列 第2行第3列 
第3行第1列 第3行第2列 第3行第3列 

你想显示a.txt中的内容,会用什么命令呢?当然是type,type a.txt 

for也可以完成同样的命令: 

for /f %%i in (a.txt) do echo %%i 

还是先从括号执行,因为含有参数/f,所以for会先打开a.txt,然后读出a.txt里面的所有内容,把它作为一个集合,并且以每一行作为一个元素,所以会产生这样的集合, 

{"第1行第1列 第1行第2列 第1行第3列", //第一个元素 

"第2行第1列 第2行第2列 第2行第3列", //第二个元素 

"第3行第1列 第3行第2列 第3行第3列"}   //第三个元素 

集合中只有3个元素,同样用%%i依次代替每个元素,然后执行do后面的命令。 

具体过程: 

用%%i代替"第1行第1列 第1行第2列 第1行第3列",执行do后面的echo %%i,显示"第1行第1列 第1行第2列 第1行第3列", 

用%%i代替"第2行第1列 第2行第2列 第2行第3列",执行echo %%i,显示"第2行第1列 第2行第2列 第2行第3列", 

依次,直到每个元素都代替完为止。 

为了加强理解/f的作用,请执行一下两个命令,对比即可明白: 

for /f %%i in (a.txt) do echo %%i //这个会显示a.txt里面的内容,因为/f的作用,会读出a.txt中 
的内容。 

for %%i in (a.txt) do echo %%i //而这个只会显示a.txt这个名字,并不会读取其中的内容。 

通过上面的学习,我们发现for /f会默认以每一行来作为一个元素,但是如果我们还想把每一行再分解更小的内容,该怎么办呢?不用担心,for命令还为我们提供了更详细的参数,使我们将每一行分为更小的元素成为可能。 

它们就是:delims和tokens 

delims 用来告诉for每一行应该拿什么作为分隔符,默认的分隔符是空格和tab键 

比如,还是上面的文件,我们执行下面的命令: 

for /f "delims= " %%i in (a.txt) do echo %%i 

显示的结果是: 

第1行第1列 
第2行第1列 
第3行第1列 

为什么是这样的呢。因为这里有了delims这个参数,=后面有一个空格,意思是再将每个元素以空格分割,默认是只取分割之后的第一个元素。 

执行过程是: 

将第一个元素"第1行第1列 第1行第2列 第1行第3列"分成三个元素:"第1行第1列" "第1行第2列" "第1行第3列",它默认只取第一个,即"第1行第1列",然后执行do后面的命令,依次类推。 

但是这样还是有局限的,如果我们想要每一行的第二列元素,那又如何呢? 

这时候,tokens跳出来说,我能做到。 

它的作用就是当你通过delims将每一行分为更小的元素时,由它来控制要取哪一个或哪几个。 

还是上面的例子,执行如下命令: 

for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i 

执行结果: 

第1行第2列 
第2行第2列 
第3行第2列 

如果要显示第三列,那就换成tokens=3。 

同时tokens支持通配符*,以及限定范围。 

如果要显示第二列和第三列,则换成tokens=2,3或tokens=2-3,如果还有更多的则为:tokens=2-10之类的。 

此时的命令为: 

for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j 

怎么多出一个%%j? 

这是因为你的tokens后面要取每一行的两列,用%%i来替换第二列,用%%j来替换第三列。 

并且必须是按照英文字母顺序排列的,%%j不能换成%%k,因为i后面是j 

执行结果为: 

第1行第2列 第1行第3列 
第2行第2列 第2行第3列 
第3行第2列 第3行第3列 

对以通配符*,就是把这一行全部或者这一行的剩余部分当作一个元素了。 

比如: 

for /f "tokens=* delims= " %%i in (a.txt) do echo %%i 

执行结果为: 

第1行第1列 第1行第2列 第1行第3列 
第2行第1列 第2行第2列 第2行第3列 
第3行第1列 第3行第2列 第3行第3列 

其实就跟for /f %%i in (a.txt) do echo %%i的执行结果是一样的。 

再如: 

for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j 

执行结果为: 

第1行第2列 第1行第3列 
第2行第2列 第2行第3列 
第3行第2列 第3行第3列 

用%%i代替第二列,用%%j代替剩余的所有 

最后还有skip合eol,这俩个简单,skip就是要忽略文件的前多少行,而eol用来指定当一行以什么符号开始时,就忽略它。 

比如: 

for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i 

结果为: 

第3行第1列 第3行第2列 第3行第3列 

用skip来告诉for跳过前两行。 

如果不加tokens=*的话,执行结果为: 

第3行第1列 

不知道怎么回事。 

再如,当a.txt内容变成: 

.第1行第1列 第1行第2列 第1行第3列 
.第2行第1列 第2行第2列 第2行第3列 
第3行第1列 第3行第2列 第3行第3列 

执行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i结果是: 

第3行第1列 第3行第2列 第3行第3列 

用eol来告诉for忽略以"."开头的行。 

同样也必须加tokens=*,否则只会显示"第3行第1列"

 

 

 

 

本文链接:批处理文件操作杂记

转载声明:本站文章若无特别说明,皆为原创,转载请注明来源:Rexdf,谢谢!^^


This entry was posted in 电脑日常 and tagged . Bookmark the permalink.

Leave a Reply

Your email address will not be published.

*

:zsmilebig: :zsadbig: :zwiredbig: :zgreenhappy: more »

This site uses Akismet to reduce spam. Learn how your comment data is processed.